Préparation d'une installation LibroOffice avec Active Directory

Sur le serveur, créer un dossier partagé Libreoffice
1. Dans l'onglet "Partage", aller dans "Partage avancé..."
2. Cliquer sur "Autorisations"
3. Donner le "Contrôle total" à "Tout le monde" (La sécurité d'accès se fera en NTFS)
Sécurité d'accès NTFS
1. Aller dans l'onglet Sécurité
2. Ajouter le groupe "Ordinateurs du domaine" en "Modification" pour écrire aussi des Logs de suivi.
  La "GPO Machine" utilisera ce compte
3. Supprimer tous les autres comptes (sauf Administrateurs et Système)
Décompresser l'un des packages LibreOffices dans ce dossier
Ajouter un dossier "log" pour le suivi du déploiement
Créer une OU pour le déploiement
Déplacer les machines dans l'ou pour appliquer la GPO
Pendant la phase de test, Configuration ordinateur -> Modèles d'administration -> Système -> Script :
valider "Afficher les instructions des scripts de démarrage pendant leur exécution"
Configuration ordinateur -> Modèles d'administration -> Système -> Script :
Valider "Exécuter les script de démarrage de manière asynchrone"
Configuration ordinateur -> Modèles d'administration -> Système -> Stratégie de groupe :
Valider "Autoriser le traitement sur une connexion réseau lente" dans "Configurer le traitement de la stratégie de script"

Assigner un script de démarrage "deploiement_Libreoffice.bat"

Exemple de batch disponible ici -> deploiement_Libreoffice.bat

Deux paramètres :
1- Mon_Serveur -> Pour le partage en réseau des sources LibreOffice et l'accès direct à perso.bat
Le dossier doit avoir des droits en "lecture et exécution" pour permettre l'installation
2- Mes_Logs -> un dossier pour le suivi du déploiement sur le serveur
Le dossier doit avoir des droits en "Modification" pour autoriser l'écriture des logs
Installation :
Un dossier "c:\GPO" est créé sur le poste installé pour poser un flag "Libreoffice_OK.txt" pour ne pas répéter l'installation à chaque démarrage.
En cas de succès :
Le dossier Mes_Logs (logs_deploiement_libreoffice) sur le serveur contiendra un fichier "OK_NOMPC1.txt"
Le dossier "c:\GPO" sur le PC (NOMPC1) contiendra un fichier "Libreoffice_OK.txt" et un fichier "Debug_partage_OK.txt"
En cas d'échec :
Le dossier Mes_Logs (logs_deploiement_libreoffice) sur le serveur contiendra un fichier "Erreur_NOMPC1.txt"
Le dossier "c:\GPO" sur le PC (NOMPC1) contiendra un fichier "Libreoffice_Erreur.txt" et tous les fichiers logs de l'installation ("LibO_...") et éventuellement fichier "Debug_partage_Erreur.txt"

@echo off
REM Déploiement Libreoffice par script de démarrage avec Active Directory
REM Auteur : Nicolas PAOUR 

REM Pré-requis :
REM Dossier partagé sur le serveur AD, exemple : \\Nom_Serveur\Libreoffice
REM Attention, le dossier "Libreoffice" doit avoir un accès minimum en "lecture et exécution" pour "Ordinateurs du domaine"
Set Mon_Serveur=\\Nom_Serveur\Libreoffice
REM Pour un test ou une installation local sur le serveur (\\Nom_Serveur), le dossier partagé ne sera pas disponible au démarrage !
REM Utiliser un dossier local, par exemple :
REM Set Mon_Serveur=D:\public\logiciels\LibreOffice

REM Création du dossier Log pour suivi du déploiement s'il n'existe pas (premier déploiement)
REM Utiliser n'importe quel dossier ou partage
REM Attention, si "logs_deploiement_libreoffice" n'existe pas, le dossier parent, ici %Mon_Serveur% doit avoir un
REM accès minimum en "Modification" pour "Ordinateurs du domaine" pour créer le dossier "logs_deploiement_libreoffice"
REM sinon, le dossier "logs_deploiement_libreoffice" doit avoir un accès minimum en "Modification" pour "Ordinateurs du domaine" 
REM pour la création des logs sur le serveur !
Set Mes_Logs=%Mon_Serveur%\logs_deploiement_libreoffice
If Not Exist "%Mes_Logs%" MKDIR "%Mes_Logs%"

REM Installation si le fichier Libreoffice_OK.txt n'existe pas
	If Not Exist "c:\GPO\Libreoffice_OK.txt" (
		REM Initialisation
			If Exist "c:\GPO" RMDIR /S /Q "c:\GPO"
			MKDIR "c:\GPO"
			REM Suppression des anciens logs pour le PC en cours d'installation
			Del /F /Q "%Mes_Logs%\Erreur_%COMPUTERNAME%.txt"
			Del /F /Q "%Mes_Logs%\OK_%COMPUTERNAME%.txt"

		REM Début installation
			call "%Mon_Serveur%\perso.bat"

		If Exist "%temp%\%Libo_TempLibo%.\LibO_install_erreur.txt" (
			REM crée sur le PC un flag d'échec Erreur_%COMPUTERNAME%.txt et copie les fichiers logs
			Echo Erreur sur LibreOffice %COMPUTERNAME% > "c:\GPO\Libreoffice_Erreur.txt" 
			copy "%temp%\%Libo_TempLibo%.\*.*" c:\GPO\*.* /Y
			
			REM crée sur le serveur AD un flag d'échec Erreur_%COMPUTERNAME%.txt
			Echo Erreur sur %COMPUTERNAME% > "%Mes_Logs%\Erreur_%COMPUTERNAME%.txt"
		) Else (
			REM Si pas d'erreur, crée un flag local Libreoffice_OK.txt pour ne plus exécuter la GPO	
			Echo Installation réussie > "c:\GPO\Libreoffice_OK.txt" 
			REM crée sur le serveur AD un Flag de succes OK_%COMPUTERNAME%.txt
			Echo Installation réussie sur %COMPUTERNAME% > "%Mes_Logs%\OK_%COMPUTERNAME%.txt"
		)		
	)
REM déboguage sur l'accès au partage
REM *************************************
If Exist %Mon_Serveur% (
Echo Le partage %Mon_Serveur% est accessible, code %ERRORLEVEL% > "c:\GPO\Debug_partage_OK.txt" 
)

If Exist %Mes_Logs% (
Echo Le dossier %Mes_Logs% est accessible, code %ERRORLEVEL% >> "c:\GPO\Debug_partage_OK.txt"
)

If Not Exist %Mon_Serveur% (
Echo Erreur %ERRORLEVEL% sur %Mon_Serveur%, le partage n'existe pas ou n'est pas accessible ! > "c:\GPO\Debug_partage_Erreur.txt" 
)

If Not Exist %Mes_Logs% (
Echo Erreur %ERRORLEVEL% sur %Mes_Logs%, le dossier Log n'est pas accessible ! >> "c:\GPO\Debug_partage_Erreur.txt"
)
REM *************************************

Dernière mise à jour : avril 2021